home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Micro on the Apple Volume 1 (1981)(Micro Ink)[no boot].zip
/
Micro on the Apple Volume 1 (1981)(Micro Ink)[no boot].do
/
SHAPE1.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
1KB
|
43 lines
10 REM ***************************
11 REM * HOW TO DO A SHAPE TABLE *
12 REM * JOHN FIGUERAS *
14 REM * *
15 REM * SHAPE1 *
16 REM * *
18 REM * COPYRIGHT (C) 1981 *
20 REM * MICRO INK, INC. *
22 REM * CHELMSFORD, MA 01824 *
24 REM * ALL RIGHTS RESERVED *
25 REM * *
26 REM ***************************
28 REM
29 REM
30 INPUT "NAME OF SHAPE TABLE ";NAME$
35 INPUT "STARTING ADDRESS, DECIMAL ";ADDR
40 INPUT "NO. OF SHAPES TO BE STORED ";N
50 REM ZERO DIRECTORY
60 FOR I = 0 TO 2 *N +1
70 POKE ADDR +I,0: NEXT
80 REM CALCULATE INDEX TO CURSOR
90 N = 2 *N +2
100 REM PUT CURSOR INDEX INTO DIRECTORY
110 POKE ADDR +2,N -256 * INT(N/256)
120 POKE ADDR +3, INT(N/256)
130 REM CALC INITIAL ADDRESS TO CURSOR
140 INIT = ADDR +N
150 REM ENTER CURSOR SHAPE VECTORS
160 DATA 62,36,45,54,04,00
170 FOR I = 0 TO 5
180 READ A: POKE INIT +I,A: NEXT
190 REM GET INDEX TO NEXT SHAPE
200 N = N +6
210 REM STORE NEW INDEX IN DIRECTORY
220 POKE ADDR +4,N -256 * INT(N/256)
230 POKE ADDR +5, INT(N/256)
240 REM UPDATE SHAPE COUNTER
250 POKE ADDR,1
260 REM STORE INITIALIZED FILE ON DISK
270 D$ = CHR$(4)
280 PRINT D$;"NOMON C,I,O"
290 PRINT D$;"BSAVE" +NAME$ +",A" + STR$(ADDR) +",L" + STR$(N) +",V0,D2"
300 END